Transcribed directly from Popular Computing Weekly / PCN (December 15-21, 1983).
Written by David Pearson of York.
1000 POKE52,28:POKE56,28:CLR
1010 FORI=7168TO7256:POKEI,PEEK(I+25600):NEXT
1020 FORJ=7168TO7256:READQ:POKEJ,Q:NEXT
5000 PRINT"{CLR}{WHITE}"
5010 POKE36879,8
5020 PRINT" {RVON} GRID BIKE "
5030 PRINT"{DOWN}YOU ARE THE DRIVER "
5040 PRINT"OF THE GRID BIKE."
5050 PRINT"YOU MUST DRIVE ROUND "
5060 PRINT"THE GRID PICKING UP"
5070 PRINT"THE PEOPLE."
5080 PRINT"AS YOU DRIVE AROUND"
5090 PRINT"THE GRID YOU LEAVE A"
5100 PRINT"TRAIL."
5110 PRINT"IF YOU RUN INTO IT"
5120 PRINT"YOU WILL BE KILLED."
5130 PRINT"Z=LEFT"
5140 PRINT"X=RIGHT"
5150 PRINT"L=UP"
5160 PRINT",=DOWN"
5170 PRINT"{CYAN} PRESS ANY KEY"
5175 PRINT"{WHITE}{DOWN}BY D.PEARSON"
5180 GETA$:IFA$=""THEN5180
5190 PRINT"{CLR}"
5200 PRINT"THIS PROGRAM LOADS THEGRAPHICS,SO LOAD IT EVERY TIME"
5300 PRINT"{HOME}{CYAN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}{DOWN}LO"+CHR$(34)+"GRID2"+CHR$(34)+",";PEEK(186);"{HOME}{DOWN}{DOWN}{DOWN}{DOWN}";
5400 POKE631,13:POKE632,82:POKE633,117:POKE634,13:POKE198,4:NEW
9000 DATA0,231,255,255,255,255,231,0
9010 DATA126,126,126,60,60,126,126,126
9020 DATA255,129,129,129,129,129,129,255
9030 DATA24,24,24,24,24,24,24,24
9040 DATA0,0,0,255,255,0,0,0
9050 DATA0,0,0,31,31,24,24,24
9060 DATA0,0,0,248,248,24,24,24
9070 DATA24,24,24,248,248,0,0,0
9080 DATA24,24,24,31,31,0,0,0
9090 DATA255,255,255,255,255,255,255,255
9100 DATA28,28,8,62,8,20,34,65,0
0 QWE=RND(1-TI)
1 CLR
2 PRINT"{CLR}{WHITE}DO YOU WANT EASY({RED}1{WHITE}) OR HARD ({RED}2{WHITE})":INPUTTYU
3 IFTYU<1ORTYU>2THEN2
5 PRINT"{CLR}":POKE36878,15:POKE36869,255
10 A=8174:GRID=1:CH=1:DF=1:WT=3:NW=3:D=-22:SC=0:MAN=1
45 POKE36879,56
50 FORN=7680TO8185:POKEN,2:NEXT
80 FORN=38400TO38905:POKEN,6:NEXT
96 FORN=7680TO8164STEP22:POKEN,9:NEXT
97 FORN=38400TO38884STEP22:POKEN,0:NEXT
98 FORN=1TOMAN:RP=INT(RND(1)*506)+7680:IFPEEK(RP)<>2THENRP=RP+1
99 POKERP,10:NEXTN
100 IFTYU=1THEN103
101 FORN=1TO10:SP=INT(RND(1)*506)+7680:IFPEEK(SP)<>2THENSP=SP+1
102 POKESP,230:POKESP+30720,0:NEXT
103 POKEA,CH:POKEA+30720,2:POKEA+(-D),WT
104 POKE36874,196:POKE36875,196:POKE36876,176
105 OD=D
106 IFNW=0THEN110
107 WT=NW
110 GETA$
120 IFA$="Z"THEND=-1:WT=4:CH=0
130 IFA$="X"THEND=1:WT=4:CH=0
140 IFA$="L"THEND=-22:WT=3:CH=1
150 IFA$=","THEND=22:WT=3:CH=1
160 A=A+D
162 IFPEEK(A)>2ANDPEEK(A)<10ORPEEK(A)=230THEN4000
163 IFPEEK(A)=10THENGOTO6100
165 GOTO3000
180 IFA<7680ORA>8185THENGOTO4000
190 GOTO103
3000 IFOD=-22ANDD=-1THENNW=4:WT=6
3010 IFOD=22ANDD=-1THENNW=4:WT=7
3020 IFOD=-22ANDD=1THENNW=4:WT=5
3030 IFOD=22ANDD=1THENNW=4:WT=8
3040 IFOD=1ANDD=22THENNW=3:WT=6
3050 IFOD=1ANDD=-22THENNW=3:WT=7
3060 IFOD=-1ANDD=-22THENNW=3:WT=8
3070 IFOD=-1ANDD=22THENNW=3:WT=5
3080 GOTO180
4000 POKE36874,0:POKE36875,0:POKE36876,0
4001 FORKN=1TO10
4002 QW=128
4010 FORN=0TO7
4020 POKE(A+-D)+30720,N
4030 POKE36877,QW
4035 QW=QW+5
4040 NEXT
4050 NEXT
4055 POKE36877,0
4060 FORJ=1TO250:NEXT
4070 POKE36869,240
4080 PRINT"{CLR}{WHITE}"
4090 POKE36879,8
4100 PRINT" {RVON} GRID BIKE "
4110 PRINT"{DOWN}{DOWN}{DOWN}YOUR SCORE=";SC
4120 IFSC>HSTHENHS=SC
4130 PRINT"{DOWN}HIGH SCORE=";HS
4140 PRINT"{DOWN}{DOWN}ANOTHER GAME(Y/N)"
4150 GETA$:IFA$=""THEN4150
4151 RESTORE
4160 IFA$="Y"THENGOTO4200
4170 IFA$="N"THENEND
4180 GOTO4150
4200 PRINT"DO YOU WANT ({YELLOW}1{WHITE})EASY OR ({YELLOW}2{WHITE})HARD"
4210 INPUTTYU
4215 IFTYU<1ORTYU>2THEN4210
4220 PRINT"{CLR}":POKE36869,255:GOTO5
6100 DF=DF+1
6102 SC=SC+10
6105 IFDF<MANTHEN165
6110 PRINT"{BLACK}":POKE36874,0:POKE36875,0:POKE36876,0
6120 PRINT"{HOME}{DOWN}{DOWN}{DOWN}{RIGHT}{RVON}GRID";GRID;"CLEARED"
6125 FORRT=1TO2500:NEXT
6130 DF=0:MAN=MAN+1:GRID=GRID+1:SC=SC+100:A=8174:D=-22:WT=3:CH=1:NW=3:GOTO45
Mission Briefing
Light cycles on the unexpanded Vic-20! You are presented with a multicoloured grid on which stranded people are located.
- Objective: Collect all stranded men (stick figures) without crashing your Grid Bike.
- Trail Warning: As your bike moves, it leaves behind a solid light trail. Running into your trail, outer walls, or obstacle blocks will result in an immediate fatal crash!
- Easy Mode: Grid contains stranded men and empty grid tiles.
- Hard Mode: Adds 10 (or more) dangerous black obstacle blocks placed by the computer across the grid!
- Level Progression: Rescuing all men on the screen clears the grid ("GRID CLEARED") and advances to the next stage with more men and tighter challenges!
